I decided to simulate the flight of the bullet, including air resistance, in Mathematica. In a rotating reference frame, the equation of motion for the bullet is
$$
m \vec{a} = -\frac{1}{2} \rho C_d A |\vec{v}|\vec{v} + 2 m \vec{\omega} \times \vec{v} + m \vec{\omega} \times (\vec{\omega} \times \vec{r}),
$$
where:
- $m$ is the mass of the bullet (I assumed 5 grams);
- $\rho$ is the density of the air (about 1.225 $\text{kg/m}^3$ on Earth);
- $C_d$ is the drag coefficient of the bullet, which I took to be 0.295 according to this random website;
- $A$ is the cross-sectional area of the bullet (I assumed a 10 mm diameter); and
- $\vec{\omega}$ is the angular velocity vector of the station. This will point along the station's axis and have a magnitude of $\sqrt{g/R}$, where $R$ is the radius of the station and $g$ is the strength of "gravity" on its inner surface. I took $g = 10 \text{ m/s}^2$ and $R = 4000$ m (at least initially).
A word about my assumptions concerning air resistance: I assumed that the quadratic drag assumption was valid at all times in the bullet's flight. This is probably a valid assumption for firearms with subsonic ammunition, but would not be a valid assumption for firearms with supersonic ammunition. To avoid this complication, I assumed a muzzle velocity of $v_0 = 200$ m/s, well below the speed of sound.
I also assumed that the air density was constant throughout the station and was rotating with the station. The bullets were "fired" from a height of 1.5 m "above" the inner surface of the station. The trajectory of the bullets was assumed to be perpendicular to the axis of the space station's rotation.
Based on this, here are my results. The blue line is the trajectory; the black curve is the outer wall of the station. Code is available at the bottom of this answer.
Horizontal firing against rotation, large station
The bullet lands about 270 m away after a time of flight of about 2 seconds. Note that this time of flight is substantially longer than a bullet dropped from a similar height on Earth (that would be about 0.55 s), since the Coriolis force is pushing "up" on the bullet. But unfortunately, since the bullet is constantly losing speed to the drag force, there is insufficient Coriolis force to maintain the circular trajectory, and it eventually hits the inner surface of the cylinder.
As pointed out in the comments, a space station could use a low-pressure pure oxygen atmosphere instead of an Earth-like atmosphere. Since the density of the air would be lower, the bullet would go further. Wikipedia says that the lowest pure-oxygen spacesuits use 20.7 kPa of oxygen, which according to the ideal gas law reduces $\rho$ to about $0.272 \text{ kg/m}^3$. Running the code with this gas density leads to a range of about 615 meters rather than 270 — farther, but still nowhere near all the way around.
Can we reduce the density sufficiently to get the bullet all the way around? From playing with the code it appears that a density of about $0.2 \text{ g/m}^3$ would do the trick. For comparison, the atmosphere of Mars has a density of about $20 \text{ g/m}^3$; a density of $0.2 \text{ g/m}^3$ is (I think) comparable to the density of Earth's atmosphere at about 60–70 km, which is getting pretty close to what some people call outer space.
Near-vertical firing, large station
It is possible for you to hit yourself with a handgun bullet on a large space station if you fire it nearly (but not quite) vertically, with a small component of the initial velocity against the rotation direction. With the given initial height and muzzle velocity I assumed, an elevation angle of about 79.5° seems to do the trick. The bullet returns after about 19.4 seconds with a speed of about 55 m/s. I don't know whether this would be fast enough to be lethal, but it would definitely leave a mark.
More baroque trajectories
It's possible to get a bullet a large fraction of the way around the space station if the space station is smaller and you fire it with a significant vertical component. Above is a a bullet fired at an elevation angle of 35° on a 400-m space station. Roughly, if the station is smaller, it is easier to fire the bullet so it gets close to the axis; and if it gets close to the axis, then the centrifugal force it feels is smaller, giving it more "hang time". However, it does not seem to be possible to get a bullet to travel around the entire space station without using this effect; and this does not fulfill the brief of a bullet that stays near the inner wall of the space station for its time of flight.
Code:
(* All numbers are in SI units *)
r = 4000.; (* station radius *)
g = 10 ; (* "gravity" at inner surface of cylinder *)
omega = Sqrt[g/r]; (* angular velocity of station *)
vst = omega r (* tangential velocity of station rim *)
period = 2 Pi/omega (* rotational period *)
m = 0.005;(* bullet mass *)
rho = 1.225; (* air density *)
cD = 0.295; (* drag coefficient for bullet *)
a = Pi*(0.010/2)^2; (* cross-sectional area of bullet *)
v0 = 200.; (* muzzle velocity *)
theta0 = 0 Degree; (* "elevation angle" for shot; 0 = "horizontal" & against rotation, 90 Degree = "vertical" *)
eoms = Thread[D[{x[t], y[t]}, {t, 2}] ==
-(1/2) (rho cD a)/m Sqrt[x'[t]^2 + y'[t]^2] {x'[t], y'[t]}
+ 2 Drop[Cross[{0, 0, omega}, {x'[t], y'[t], 0}], -1]
+ omega^2 {x[t], y[t]}]
ics = {x[0] == 0, y[0] == -(r - 1.5), x'[0] == v0 Cos[theta0], y'[0] == v0 Sin[theta0], WhenEvent[x[t]^2 + y[t]^2 == r^2, "StopIntegration"]}
solution = First[NDSolve[Join[eoms, ics], {x, y}, {t, 0, 2 period}]];
tend = (x["Domain"] /. solution)[[1, 2]] (* time of flight *)
{x[tend], y[tend]} /. solution (*landing coordinates *)
Norm[{x'[tend], y'[tend]}] /. solution (*landing velocity*)
ParametricPlot[{x[t], y[t]} /. solution, {t, 0, tend}, Epilog -> Circle[{0, 0}, r]]
